Instanz Daten aus ColdFusion 9 ORM Entity auslesen

Wie so viele andere auch, war ich vor CF9 gewohnt in Datenbeans eine "Instance"-Struktur als Memento-Speicher für die instanzierten Daten eines Objekts aufzubauen. Die Instance-Struktur ist sehr praktisch. Lässt sich doch mit einer Methode getMemento() die aktuellen Eigenschaftwerte der Instanz zur Laufzeit auslesen. Das ist äusserst hilfreich beim Debuggen oder auch um die Daten an einen AJAX-Request oder in eine Form zurückzuspielen.

Beispiel vor CF9:
<cfcomponent> <cfset variables.instance = StructNew() /> <cffunction name="init" access="public" returntype="any" output="false"> <cfargument name="prop" default=""/> <cfset setProp(arguments.prop)/> <cfreturn this/> </cffunction <cffunction name="setProp" access="public" returntype="void" output="false"> <cfargument name="Prop" type="string" required="true" /> <cfset variables.instance.Prop = arguments.Prop /> </cffunction> <cffunction name="getProp" access="public" returntype="string" output="false"> <cfreturn variables.instance.Prop /> </cffunction> <cffunction name="getMemento" output="false" access="public"> <cfreturn instance> </cffunction> </cfcomponet

In CF9 haben wir ja jetzt implizite Getter/Setter. Die müssen also nicht mehr extra geschrieben werden, was kaum jemand beklagen dürfte, zumal sie ja immer auch überschrieben werden können. Gespeichert werden die Eigenschaftswerte zur Laufzeit aber im Variables-Scope. Das direkte Auslesen der gesamte Instanzdaten wird dadurch erschwert. Schöne wäre IMHO, Instanzdaten hätten einem eignen Scope, aber der This-Scope bezeichnet in CFML leider eine ganz andere Funktion als in Java.

Trotzdem lassen sich aber mit den Metadaten der Properties die Laufzeitdaten auslesen. Auf "Adobe Cookbook" findet sich denn auch bereits eine Funktion, die genau dies macht:

http://cookbooks.adobe.com/post_A_getMemento___method_when_using_implicit_getter_a-16334.html

So weit so gut, doch was passiert, wenn im Klassendesign Vererbung benutzt wird? Obige Funktion berücksichtigt das nicht. Da erinnerte ich mich doch an meine noch mit CF6 geschriebene Activce-Record Persistancekomponente. Auch dort lese ich die Laufzeitwerte über die Metadaten des <cfproperty> Tags aus - aber rekursive, um auch die vererbten Eigenschaften auszulesen. Also ab ins eigene Code-Depot...

Unten nun der für CF9 angepasste Code. Er liesst Instance-Daten auch aus vererbten Objekten aus. Um die Methode übergreifend in allen Entity-Objekten zu verwenden, erstellte ich eine Abstrakte Klassen, von der sich alle Entities ableiten.

component  hint="I am an abstract class for entities" output="false"
{
/*======================================================================================
  Purpose: Abstract Entity
  Created By: Daniel Schmid
  History: 18. Nov. 2009
  ----------------------------------------------------------------------------------------
  I am a abstract class and should never be instantiated directly, only extended.
  ========================================================================================*/
  
  /**
* @hint  get the properties from a specific meta data or component instance (by default, this)
* @output false
*/
public struct function getProperties(
  required struct metaDataToCheck = getMetaData(this)
  )
{ 
  var i = -1;
  var theseProperties = structnew();
  var thisProperty = "";
  var md = arguments.metaDataToCheck;
  //if this metaData has properties, loop through them, populating a struct of properties
  if(structKeyExists(md,"properties")){
     for(i = 1; i LTE arrayLen(md.properties); i = i + 1){
       thisProperty = md.properties[i];
       theseProperties[thisProperty.name] = thisProperty;
     }
  }
  return theseProperties;
}
/**
* @hint  a method for traversing the metaData to get properties up the tree, by default, looks at this
* @output false
*/
public struct function getAllProperties(
  required struct metaDataToCheck = getMetaData(this)
  )
{
  var ii = 1;
  var allProperties = structnew();
  var md = getMetaData(arguments.metaDataToCheck);
 
  //if this component is extended, recurse up the tree
  if(structKeyExists(arguments.metaDataToCheck,"extends")){
    allProperties = getAllProperties(arguments.metaDataToCheck.extends);
  }
  //append these properties to allProperties; allow overwrite to allow children properties to  over-ride parents
  structAppend(allProperties,getProperties(arguments.metaDataToCheck),true);
  return allProperties;
}
public struct function getMemento()
{
  var instance = structNew();
  for(key in getAllProperties()){
    if(structKeyExists(variables,key))
      instance[key] = variables[key];
  }
  return instance;
}
/**
* @hint  return properties structures in an array
* @output false
*/ 
 public array function getAllPropertiesArray()
 {
  var allProps = getAllProperties();
  var aProperties = arraynew(1);
  for(key in allProps){
    prop = allProps[key];
    arrayappend(aProperties,prop);
  }
  return aProperties;
 }
  
}